Second order cosmological perturbations and gauge transformations

Preliminaries

Load tensor package

<<xAct`xPand`

Nicer printing

$PrePrint=ScreenDollarIndices;

$CovDFormat="Prefix";

$DefInfoQ=False;

Object definitions

Spacetime manifold

The spacetime manifold M, on which tensors will be defined. Some Greek letters are defined as tangent space indices.

DefManifold[M,4,{α,β,γ,ζ,λ,μ,ν,ω,τ,ο}]

Metric

The background metric g of signature (-,+,+,+). The Levi-Civita derivative of a tensor (Subscript[A, μ]) will be written as (Subscript[▽, μ])(Subscript[A, ν]) in prefix notation or (Subscript[A, ν;μ]) in postfix notation. Note that this is not the physical metric; the latter will be defined later as a² times this metric, where a is the scale factor.

DefMetric[-1,Met[-α,-β],CD,{";","▽"},PrintAs->"g"]

FLRW background geometry

We now define the cosmologically symmetric background geometry. Here we choose a spatially curved Friedmann-Lemaître-Robertson-Walker background metric. The physical metric, which will be called gah2, is defined automatically by xPand.

SetSlicing[Met, Orth,SMet,SD,{"|","D"},"FLCurved"]

For the spatial part of the metric, we will use the letter h.

PrintAs[SMet]^="h"

The unit normal (co-)vector field will be denoted n.

PrintAs[Orth]^="n"

Metric perturbation

Next, we define the metric perturbations. These are given as follows.

DefMetricFields[Met,δMet,SMet]

Matter perturbation

Also for the matter fields we need a perturbation, defined as follows.

DefMatterFields[Vel,δVel,SMet]

Gauge transforming vector field

This is the vector field which we will use for gauge transformations.

DefTensor[Evaluate[ξ[SMet]][LI[0],μ],M]

Second order perturbations

Metric tensor

We first take a look at the general conventions used for the higher order metric perturbation. In the series expansion we keep the expansion parameter ϵ as well as the factor n! from the Taylor series in front of the perturbation. Note that the metric shown here is not the physical metric, but the conformally rescaled metric:

Met[-α,-β];
Perturbed[%,3]

The physical metric carries an additional scaling factor:

Met[-α,-β];
Conformal[Met,MetaSMet2][%]
Perturbed[%,3]

Since the scale factor appears as a common factor, we will omit it in the following. The first term is the background. It is assumed to be a Friedmann-Lemaitre-Robertson-Walker metric:

VisualizeTensor[δMet[LI[0],-α,-β]/.SplitMetric[Met,δMet,SMet,"AnyGauge"],SMet]

Each order of the metric perturbations is then further decomposed into its scalar, vector and tensor components. The approach for higher orders is identical to that for the linear order, which we have encountered before.

VisualizeTensor[δMet[LI[1],-α,-β]/.SplitMetric[Met,δMet,SMet,"AnyGauge"],SMet]

VisualizeTensor[δMet[LI[2],-α,-β]/.SplitMetric[Met,δMet,SMet,"AnyGauge"],SMet]

VisualizeTensor[δMet[LI[3],-α,-β]/.SplitMetric[Met,δMet,SMet,"AnyGauge"],SMet]

Velocity

Next, we take a look at the velocity. It is expanded in the same form as the metric. Note that we write it with an upper index.

Vel[α];
Perturbed[%,3]

In this case, the background is given by the unit normal vector field. Note that also here a conformal scale factor is omitted, so that the velocity shown is normalized with the conformal background metric, not the physical one:

VisualizeTensor[δVel[LI[0],α]/.SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1]/.SplitMetric[Met,δMet,SMet,"AnyGauge"],SMet]

Then we look at the first order perturbation. Here the time component is fixed by the demand that the full, perturbed velocity is normalized with respect to the full, perturbed metric. The spatial components are then decomposed into a scalar and a divergence-free vector.

VisualizeTensor[δVel[LI[1],α]/.SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1]/.SplitMetric[Met,δMet,SMet,"AnyGauge"],SMet]

The same holds for the second order. Note that the time component now also contains contributions from the first order metric and velocity.

VisualizeTensor[δVel[LI[2],α]/.SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",2]/.SplitMetric[Met,δMet,SMet,"AnyGauge"],SMet]

To see where these contributions come from, we take a brief look at the normalization. At each order, the variation of the normalization factor -1 must vanish.

Perturbation[Met[-α,-β]Vel[α]Vel[β],1]
SplitPerturbations[%,Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1],SplitMetric[Met,δMet,SMet,"AnyGauge"]],SMet]

Perturbation[Met[-α,-β]Vel[α]Vel[β],2]
SplitPerturbations[%,Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",2],SplitMetric[Met,δMet,SMet,"AnyGauge"]],SMet]

Energy-momentum tensor

Let us now take a look at the energy-momentum tensor. For a perfect fluid, it takes the usual form - written here with mixed indices, which is how one usually finds it in the literature on cosmological perturbations in general relativity.

enmom=(ρVel[]+PVel[])Vel[α]Vel[-β]+PVel[]Met[α,-β]

One reason for writing it in this form is that one can easily define the density as the negative of the eigenvalue of the velocity, at any perturbation order.

Vel[-α]Vel[β]enmom;
%/.Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1],SplitMetric[Met,δMet,SMet,"AnyGauge"]];
Expand[%]

Perturbation[Vel[-α]Vel[β]enmom,1];
ExpandPerturbation[%];
%/.Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1],SplitMetric[Met,δMet,SMet,"AnyGauge"]];
NoScalar[%];
%/.Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1],SplitMetric[Met,δMet,SMet,"AnyGauge"]];
Expand[%]

Further, the trace can be used to identify the pressure.

delta[-α,β]enmom;
SplitPerturbations[%,Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1],SplitMetric[Met,δMet,SMet,"AnyGauge"]],SMet]

Perturbation[delta[-α,β]enmom,1];
ExpandPerturbation[%];
SplitPerturbations[%,Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1],SplitMetric[Met,δMet,SMet,"AnyGauge"]],SMet]

We now take a closer look at the components of the energy-momentum tensor in the space-time decomposition. At the background it is diagonal, with the time and space components given by the density and the pressure. This is the most general form compatible with the cosmological symmetry of the background.

enmom;
Conformal[Met,MetaSMet2][%];
SplitPerturbations[%,Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1],SplitMetric[Met,δMet,SMet,"AnyGauge"]],SMet];
VisualizeTensor[%,SMet]

We then look at the first order perturbation. Here we see only such perturbations which are obtained as perturbations of the density, pressure and velocity and thus retain the perfect fluid form. In general, one may also consider anisotropic stress as a perturbation, but this cannot be expressed as a perturbation of the aforementioned variables.

enmom;
Conformal[Met,MetaSMet2][%];
Perturbation[%,1];
ExpandPerturbation[%];
SplitPerturbations[%,Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",1],SplitMetric[Met,δMet,SMet,"AnyGauge"]],SMet];
VisualizeTensor[%,SMet]

At the second order, the result becomes rather lengthy, and we only display it for completeness.

enmom;
Conformal[Met,MetaSMet2][%];
Perturbation[%,2];
ExpandPerturbation[%];
SplitPerturbations[%,Join[SplitMatter[Vel,δVel,-1,SMet,"AnyGauge",2],SplitMetric[Met,δMet,SMet,"AnyGauge"]],SMet];
VisualizeTensor[%,SMet]

Gauge transformations

Metric tensor

We first consider a linear gauge transformation of the metric. It is well known that this is given by the Lie derivative of the background metric.

GaugeChange[δMet[LI[1],-α,-β],ξ[SMet]]

By performing an irreducible decomposition of the metric and the gauge transforming vector field, whose time and space components are denoted T and L here, we can see the gauge transformation of the irreducible components of the metric tensor. Note that scalar, vector and tensor components are separated and do not mix.

SplitFieldsAndGaugeChange[Met[-α,-β],Met,δMet,Vel,δVel,SMet,1];
ExtractOrder[%,1];
VisualizeTensor[%/aSMet[]^2,SMet]

At the second order, the gauge transformation also involves terms quadratic in first order perturbations.

GaugeChange[δMet[LI[2],-α,-β],ξ[SMet]]

Decomposing this into irreducible parts, we see that the second order perturbations, which appear linearly, still split into scalar, vector and tensors. The quadratic first order perturbations, however, now combine into different parts, for which no explicit decomposition can be given.

SplitFieldsAndGaugeChange[Met[-α,-β],Met,δMet,Vel,δVel,SMet,2];
ExtractOrder[%,2];
VisualizeTensor[%/aSMet[]^2,SMet]

Energy-momentum tensor

Finally, we take a brief look at the gauge transformation of the energy-momentum tensor and its constituents. The energy density and pressure are scalars, whose background value depends on time only, and so at the first order only their time derivatives enters the gauge transformation.

SplitFieldsAndGaugeChange[ρVel[],Met,δMet,Vel,δVel,SMet,1];
ExtractOrder[%,1]

SplitFieldsAndGaugeChange[PVel[],Met,δMet,Vel,δVel,SMet,1];
ExtractOrder[%,1]

At the second order, one needs both time and space derivatives of the first order perturbation.

SplitFieldsAndGaugeChange[ρVel[],Met,δMet,Vel,δVel,SMet,2];
ExtractOrder[%,2]

SplitFieldsAndGaugeChange[PVel[],Met,δMet,Vel,δVel,SMet,2];
ExtractOrder[%,2]

We then take a look at the velocity. This transforms as a four-vector. Note that the time component, which is fixed by the normalization, reflects the gauge transformation of the time component of the metric.

SplitFieldsAndGaugeChange[Vel[α],Met,δMet,Vel,δVel,SMet,1];
ExtractOrder[%,1];
VisualizeTensor[aSMet[]%,SMet]

At the second order, again, we get numerous mixed terms.

SplitFieldsAndGaugeChange[Vel[α],Met,δMet,Vel,δVel,SMet,2];
ExtractOrder[%,2];
VisualizeTensor[aSMet[]%,SMet]

Finally, we show how the aforementioned transformations combine into the transformation of the energy-momentum tensor. At the linear order, the result is familiar, and retains the form of a perfect fluid.

SplitFieldsAndGaugeChange[enmom,Met,δMet,Vel,δVel,SMet,1];
ExtractOrder[%,1];
VisualizeTensor[%,SMet]

At the second order, the quadratic terms do not have the form of a perfect fluid anymore, but contain an anisotropic contribution. This can most easily be seen from the spatial part, which is no longer diagonal.

SplitFieldsAndGaugeChange[enmom,Met,δMet,Vel,δVel,SMet,2];
ExtractOrder[%,2];
VisualizeTensor[%,SMet]