Tensor perturbations of Einstein’s equations

Preliminaries

Load tensor package

<<xAct`xPand`

Nicer printing

$PrePrint=ScreenDollarIndices;

$CovDFormat="Prefix";

$DefInfoQ=False;

Object definitions

Spacetime manifold

The spacetime manifold M, on which tensors will be defined. Some Greek letters are defined as tangent space indices.

DefManifold[M,4,{α,β,γ,ζ,λ,μ,ν,ω,τ,ο}]

Metric

The background metric g of signature (-,+,+,+). The Levi-Civita derivative of a tensor (Subscript[A, μ]) will be written as (Subscript[▽, μ])(Subscript[A, ν]) in prefix notation or (Subscript[A, ν;μ]) in postfix notation. Note that this is not the physical metric; the latter will be defined later as a² times this metric, where a is the scale factor.

DefMetric[-1,Met[-α,-β],CD,{";","▽"},PrintAs->"g"]

FLRW background geometry

We now define the cosmologically symmetric background geometry. Here we choose a spatially curved Friedmann-Lemaître-Robertson-Walker background metric. The physical metric, which will be called gah2, is defined automatically by xPand.

SetSlicing[Met, Orth,SMet,SD,{"|","D"},"FLCurved"]

PrintAs[SMet]^="h"

PrintAs[Orth]^="n"

Metric perturbation

Finally, we define the metric perturbations. These are given as follows.

DefMetricFields[Met,δMet,SMet]

Further ingredients

Tensor perturbations

In this calculation we want to assume only tensor perturbations. These are given by the following tensor field in xPand, where the first index describes the perturbation order:

EtSMet[LI[1],-α,-β]

By the following definition, we set the perturbation of the conformally rescaled metric (which is the physical metric divided by the square of the scale factor) to the tensor perturbations only.

tensors={δMet[LI[ord_],α_,β_]:>2EtSMet[LI[ord],α,β]}

Helper function

In the following, it will be helpful to define a function which performs a few steps automatically. This function first performs a conformal transformation from the conformally related, symmetric metric to the physical spacetime metric, then inserts the pure tensor perturbations, shows the result in a 3+1 decomposition and finally returns it.

pertexp[expr_]:=Module[{term=expr},term=Conformal[Met,MetaSMet2][term];term=SplitPerturbations[term,tensors,SMet];If[term=!=0,Print[VisualizeTensor[term,SMet]]];Return[term]]

Perturbation of the Einstein tensor

Expected result

The tensor we need to calculate is the perturbation of the Einstein tensor with mixed indices. For convenience, we lower one index again after calculating the perturbation. The formula is actually well known:

Met[-α,-γ]Perturbation[EinsteinCD[γ,-β],1]
ptotal=ExpandPerturbation[%];
ttotal=pertexp[%]

Extracting the inverse metric

This can also be calculated in two steps, namely by perturbing the Einstein tensor with lower indices, and adding a correction term from the perturbation of the inverse metric, which is used to raise one index:

Perturbation[EinsteinCD[-α,-β],1]
plower=ExpandPerturbation[%];
tlower=pertexp[%]

-δMet[LI[1],-α,-ζ]Met[ζ,γ]EinsteinCD[-γ,-β]
pinvmet=ExpandPerturbation[%];
tinvmet=pertexp[%]

We check that their sum indeed yields the perturbation we calculated above.

plower+pinvmet-ptotal;
Expand[%];
ToCanonical[%];
Simplify[%];
ToCanonical[%]

tlower+tinvmet-ttotal;
Expand[%];
ToCanonical[%]

Einstein tensor with lower indices

To gain a better insight in how this result has been calculated, we break it into single terms, which we then calculate one by one.

plower;
Expand[%];
SeparateMetric[][%];
ToCanonical[%]
pterms=List@@%;

Step-by-step calculation

Trace term

First note that by definition, the tensor perturbation is spatial and trace-free:

Met[γ,ζ]Perturbation[Met[-γ,-ζ],1]
pertexp[%]

Hence, the same holds also for its second covariant derivative, and so the corresponding terms vanish.

Met[γ,ζ]CD[-α][CD[-β][Perturbation[Met[-γ,-ζ],1]]]
pertexp[%]

Contraction with Ricci tensor

For the cosmologically symmetric Friedmann-Lemaître-Robertson-Walker background, also the spatial components of the Ricci tensor are proportional to the background metric components.

RicciCD[-μ,-ν]
pertexp[%]

Hence, their contraction with the tensor perturbation vanishes.

RicciCD[-μ,-ν]Met[γ,μ]Met[ζ,ν]Perturbation[Met[-γ,-ζ],1]
pertexp[%]

Divergence term

Next, we use the fact that the tensor perturbation is also divergence-free. This allows us to calculate

Met[γ,ζ]CD[-ζ][Perturbation[Met[-γ,-α],1]]
pertexp[%]

Reordered divergence terms

There are two more terms which appear like divergences, but their covariant derivatives are in the wrong order. Recall that changing the order of covariant derivatives introduces curvature tensors (and in general also torsion tensors, but these vanish for the Levi-Civita connection):

CommuteCovDs[CD[-μ][CD[-α][Perturbation[Met[-ν,-β],1]]],CD,{-α,-μ}]
Expand[%]

Now the second order derivative term indeed reproduces the divergence which we previously calculated. For the remaining two terms, taking into account their coefficient in the perturbation of the Einstein tensor, we find the expressions

prediva1=-Met[μ,ν]RiemannCD[-α,-μ,-β,γ]Perturbation[Met[-ν,-γ],1]/2
trediva1=pertexp[%]

prediva2=-Met[μ,ν]RiemannCD[-α,-μ,-ν,γ]Perturbation[Met[-γ,-β],1]/2
trediva2=pertexp[%]

Note that each of these terms appears once again, but with the opposite order of the free indices.

predivb1=-Met[μ,ν]RiemannCD[-β,-μ,-α,γ]Perturbation[Met[-ν,-γ],1]/2
tredivb1=pertexp[%]

predivb2=-Met[μ,ν]RiemannCD[-β,-μ,-ν,γ]Perturbation[Met[-γ,-α],1]/2
tredivb2=pertexp[%]

The result is the same, since the terms are symmetric in these indices. This is easily checked:

prediva1-predivb1;
pertexp[%]

prediva2-predivb2;
pertexp[%]

trediva1-tredivb1

trediva2-tredivb2

Ricci scalar term

For the term involving the Ricci scalar, we calculate first its background value.

RicciScalarCD[]
pertexp[%]

Hence, its product with the metric perturbation, together with the coefficient in the Einstein tensor, is given by

pricsca=-RicciScalarCD[]Perturbation[Met[-α,-β],1]/2
tricsca=pertexp[%]

Second derivative term

The last term in the perturbation of the lower index Einstein tensor involves second order covariant derivatives of the perturbations. Calculating these is more tedious, but straightforward.

psecond=-Met[γ,ζ]CD[-γ][CD[-ζ][Perturbation[Met[-α,-β],1]]]/2
tsecond=pertexp[%]

Inverse metric term

For completeness, we recall once more the term obtained by raising one index of the Einstein tensor before calculating its perturbation. This is obtained from the background value of the Einstein tensor, which is given as follows.

EinsteinCD[-μ,-ν]
pertexp[%]

Indeed, here we recognize the term calculated earlier.

-δMet[LI[1],-α,-ζ]Met[ζ,γ]EinsteinCD[-γ,-β]
pertexp[%]
%-tinvmet

Final result

Lower indices

We first check that we have correctly expanded the perturbation of the Einstein tensor with lower indices.

prediva1+prediva2+predivb1+predivb2+pricsca+psecond;
pertexp[%]
%-tlower

Mixed indices

Taking into account also the inverse metric term, we obtain the desired result.

prediva1+prediva2+predivb1+predivb2+pricsca+psecond+pinvmet;
pertexp[%]
%-ttotal