Harmonic expansion of the metric tensor

Preliminaries

Load tensor package

<<xAct`xPert`

Nicer printing

$PrePrint=ScreenDollarIndices;

$CovDFormat="Prefix";

Object definitions

Spacetime manifold

The spacetime manifold M, on which tensors will be defined. Some Greek letters are defined as tangent space indices.

DefManifold[M,4,{α,β,γ,μ,ν,ρ,σ,ω,τ,θ,ϕ,κ,ξ,ζ,ϑ,φ}]

Metric

The metric g of signature (-,+,+,+). The Levi-Civita derivative of a tensor (Subscript[A, μ]) will be written as (Subscript[▽, μ])(Subscript[A, ν]) in prefix notation or (Subscript[A, ν;μ]) in postfix notation.

DefMetric[{3,1,0},Met[-μ,-ν],CD,{";","▽"},PrintAs->"g"]

We will work with tensor densities. This will make sure that the covariant derivative acts correctly on densities.

WeightedWithBasis[CD]^=AIndex;

Perturbations of the metric are written as δg.

DefMetricPerturbation[Met,δMet,ϵ,PrintAs->"δg"]

Inverse metric density

This defines the “gothic metric”, or densitized inverse metric (𝔤^(μν))=(g^(μν))(Sqrt[-g]).

DefTensor[DIMet[μ,ν],M,Symmetric[{1,2}],WeightOfTensor->AIndex,PrintAs->"𝔤"]

We then define the metric perturbation as (h^(μν))=(𝔤^(μν))-(η^(μν)).

DefTensorPerturbation[hh[LI[0],μ,ν],DIMet[μ,ν],{M},Symmetric[{2,3}],PrintAs->"h"]

For the inverse of the gothic metric, we write (Subscript[(OverBar[𝔤]), μν]).

DefTensor[DMet[-μ,-ν],M,Symmetric[{1,2}],WeightOfTensor->-AIndex,PrintAs->"(OverBar[𝔤])"]

Finally, it will be convenient to define (Subscript[(OverBar[h]), μν])=(Subscript[(OverBar[𝔤]), μν])-(Subscript[η, μν]).

DefTensorPerturbation[ihh[LI[0],-μ,-ν],DMet[-μ,-ν],{M},Symmetric[{2,3}],PrintAs->"(OverBar[h])"]

Minkowski metric

We also define the Minkowski metric as a flat metric:

DefMetric[{3,1,0},Mink[-μ,-ν],PD,{",","∂"},FlatMetric->True,PrintAs->"η"]

Energy-momentum tensor

For working with the Einstein equations, we need the energy-momentum tensor.

DefTensor[EnMom[μ,ν],M,Symmetric[{1,2}],PrintAs->"T"]

Gravitational constant

This is the gravitational constant, which also enters the Einstein equations.

DefConstantSymbol[NewtG,PrintAs->"G"]

Tensors in densitized language

Metric

We start be defining a few helpful rules, which will be used later through the calculations. First, we declare that (Subscript[(OverBar[𝔤]), μν]) shall be the inverse of (𝔤^(μν)). Hence, contractions will evaluate to the Kronecker symbol.

ggru=Union[Flatten[MakeRule[#,MetricOn->None,ContractMetrics->False]&/@{{DIMet[μ,ρ]DMet[-ν,-ρ],delta[-ν,μ]},{DIMet[ρ,μ]DMet[-ρ,-ν],delta[-ν,μ]},{DIMet[ρ,μ]DMet[-ν,-ρ],delta[-ν,μ]},{DIMet[μ,ρ]DMet[-ρ,-ν],delta[-ν,μ]}}]]

Another consequence is that the derivative of the lower index gothic metric is expressed in terms of derivatives of the upper index version. This is given by the following rule.

dgru=MakeRule[{PD[-ρ][DMet[-μ,-ν]],-DMet[-μ,-α]DMet[-ν,-β]PD[-ρ][DIMet[α,β]]},MetricOn->None,ContractMetrics->False]

Christoffel symbols

Now we will calculate the Christoffel symbols in terms of the gothic metric. This can be done using the fact that the gothic metric is covariantly constant, just like the normal metric. Hence, the following expression vanishes, also after lowering indices. Also note the appearance of the trace of the Christoffel symbol, since the gothic metric is a tensor density and not a tensor.

CD[-ρ][DIMet[α,β]]
DMet[-μ,-α]DMet[-ν,-β]%;
ChangeCovD[%,CD,PD];
Expand[%];
del1=%//.ggru

To derive a formula for a single Christoffel symbol, we use the same trick as when calculating them in terms of the metric. The following recombination of indices gives us just one Christoffel symbol, plus some traces.

del1-2Antisymmetrize[del1,{-μ,-ρ}]-2Antisymmetrize[del1,{-ν,-ρ}];
del2=ToCanonical[%,UseMetricOnVBundle->None]

Next, we must eliminate the traces. By contracting two indices from the (vanishing) expression above, we get that also the following vanishes.

-DIMet[ν,ρ]del2/2;
Expand[%];
%//.ggru;
del3=ToCanonical[%,UseMetricOnVBundle->None]

Now this is the desired relation that gives us the trace. We use it to eliminate the trace from the last equation, and finally get a solution for the Christoffel symbol.

DMet[-ν,-ρ]del3+DMet[-μ,-ρ](delta[-ν,μ]del3)-DMet[-μ,-ν](delta[-ρ,μ]del3)+del2;
DIMet[ρ,σ]%/2;
Expand[%];
%//.ggru;
chru=MakeRule[{ChristoffelCD[σ,-μ,-ν],Evaluate[ChristoffelCD[σ,-μ,-ν]-%]},MetricOn->None,ContractMetrics->False];(#==(#/.chru))&[ChristoffelCD[ρ,-μ,-ν]]

Riemann tensor

Since now we have a formula for the Christoffel symbols, it is easy to calculate curvature expressions. Here we show this for the Riemann tensor. We know how it is expressed in terms of the Christoffel symbols, and so we can use the formula above. Also we can calculate derivatives, since we know how they act on the gothic metric and its inverse.

RiemannCD[-σ,-ρ,-ν,μ]
ChangeCurvature[%,CD,PD]
%/.chru;
%/.dgru;
Expand[%];
%//.ggru;
ToCanonical[%,UseMetricOnVBundle->None]

Ricci tensor

With the knowledge from above, we can continue and calculate the Ricci tensor. Here we go one step further: we raise its indices with the gothic metric, and so we obtain a tensor density of weight +2. Note how density factors are fully absorbed in the gothic metric.

DIMet[μ,α]DIMet[ν,β]RicciCD[-α,-β]
ChangeCurvature[%,CD,PD];
%/.chru;
%/.dgru;
Expand[%];
%//.ggru;
ToCanonical[%,UseMetricOnVBundle->None]

Einstein tensor

In the same spirit, we also raise the indices of the Einstein tensor with the gothic metric. Note here in particular the second term, where we have combined the density factors with the metric that is used to obtain the Ricci scalar. The result is not too lengthy.

DIMet[μ,α]DIMet[ν,β]RicciCD[-α,-β]-RicciCD[-ρ,-σ]DIMet[ρ,σ]DIMet[μ,ν]/2
ChangeCurvature[%,CD,PD];
%/.chru;
%/.dgru;
Expand[%];
%//.ggru;
eins=ToCanonical[%,UseMetricOnVBundle->None]

Harmonic gauge

Gauge condition

Recall that the harmonic gauge condition can be written as demanding that the contraction of the lower indices of the Christoffel symbols with the metric vanishes. Here we can equivalently use the gothic metric, which differs from the normal metric just by a density factor, which does not alter the equation. We see that the harmonic gauge condition just becomes a condition on the divergence.

DIMet[μ,ν]ChristoffelCD[ρ,-μ,-ν]
%/.chru;
Expand[%];
%//.ggru;
ToCanonical[%,UseMetricOnVBundle->None]

We implement this condition as a rule. We also add a few higher derivatives, so that the rule finds them more easily.

hgru=Flatten[MakeRule[{#,0},MetricOn->None,ContractMetrics->False]&/@{PD[-α][DIMet[α,β]],PD[-α][PD[-γ][DIMet[α,β]]],PD[-α][PD[-γ][PD[-ζ][DIMet[α,β]]]]}]

A simple test shows that we are right.

DIMet[μ,ν]ChristoffelCD[ρ,-μ,-ν]
%/.chru;
Expand[%];
%//.ggru;
%/.hgru;
ToCanonical[%,UseMetricOnVBundle->None]

Einstein tensor

Now we apply the harmonic gauge condition to the Einstein tensor. This indeed simplifies the result. Note that only one term with second order derivatives remains, which is just given by the (densitized) d’Alembert operator.

einshg=eins/.hgru

Einstein equations

Together with the energy-momentum tensor, we get the Einstein equations. Note that since we raised the indices with the gothic metric, and obtained a density of weight +2, we must respect this also for the energy-momentum tensor. Here we multiply with -det g, and then move all factors to the geometry side.

einsru=MakeRule[{EnMom[μ,ν],Evaluate[-einshg/8/Pi/NewtG/DetMet[]]},MetricOn->None,ContractMetrics->False];

This is what the equations look like. We check our rule, which makes them vanish.

2(einshg+8Pi NewtG EnMom[μ,ν]DetMet[]);
feqhg=Expand[%]
%/.einsru;
Expand[%]

Energy-momentum conservation

Covariant conservation

Next, we check how energy-momentum conservation can be found in the field equations. Here we define a rule which applies the covariant conservation law by replacing the non-covariant divergence of the energy-momentum tensor by Christoffel symbols.

consru=MakeRule[{PD[-μ][EnMom[μ,ν]],-ChristoffelCD[μ,-μ,-ρ]EnMom[ρ,ν]-ChristoffelCD[ν,-μ,-ρ]EnMom[μ,ρ]},MetricOn->None,ContractMetrics->False]

Metric substitutions

In the next step, we will encounter derivatives of the metric. Also those turn into Christoffel symbols.

dmru=MakeRule[{PD[-ρ][Met[-μ,-ν]],ChristoffelCD[σ,-ρ,-μ]Met[-σ,-ν]+ChristoffelCD[σ,-ρ,-ν]Met[-μ,-σ]},MetricOn->None,ContractMetrics->False]

Finally, we will replace the appearing metric by the gothic one.

mgru=Flatten[MakeRule[#,MetricOn->None,ContractMetrics->False]&/@{{Met[μ,ν],DIMet[μ,ν]/Sqrt[-DetMet[]]},{Met[-μ,-ν],DMet[-μ,-ν]Sqrt[-DetMet[]]}}]

Divergence equation

We now calculate the ordinary, non-covariant divergence of the field equations. Then we substitute the covariant energy-momentum conservation, to cancel the derivative acting on the energy-momentum tensor. We replace the remaining energy-momentum tensor by imposing the field equations. Also Christoffel symbols and the ordinary metric are replaced by the gothic metric. Finally, we impose the harmonic gauge. The result vanishes.

PD[-μ][feqhg];
%/.consru/.dmru/.chru/.einsru/.mgru/.dgru;
Expand[%];
%//.ggru;
%/.hgru;
ToCanonical[%,UseMetricOnVBundle->None]

Perturbative expansion

Set background to Minkowski metric

The full power of the harmonic expansion becomes apparent when we consider a perturbation (𝔤^(μν))=(η^(μν))+(h^(μν)) around the Minkowski metric. This implements the background.

bgru={DMet->Mink,DIMet->InvMink};

Perturbation of the inverse

We also use the formula for the n’th order perturbation of an inverse metric. Here it works just the same way for a density.

ihh[LI[k_Integer/;k>0],-μ_,-ν_]:=Module[{ρ,σ,j},-DMet[-ν,-σ]Sum[Binomial[k,j]ihh[LI[k-j],-μ,-ρ]hh[LI[j],ρ,σ],{j,k}]]

These are the lowest orders.

TableForm[ScreenDollarIndices[Expand[Table[ihh[LI[k],-μ,-ν],{k,3}]]]]

Vacuum equations

For simplicity, we consider only the vacuum equations below.

vfeqhg=feqhg/.{EnMom->Zero}

Perturbation around Minkowski metric

Now we are ready to come to the final result. We find that at each order in the expansion, we find a formula for the d’Alembertian of the corresponding perturbation, with products of lower order terms as the source. This is a general formula.

ddη[k_]:=(#==ToCanonical[Expand[#-Perturbation[vfeqhg,k]/.bgru],UseMetricOnVBundle->None])&[InvMink[α,β]PD[-β][PD[-α][hh[LI[k],μ,ν]]]]

At the first order, we just get the homogeneous wave equation. This we have seen already when we studied the linearized field equations alone.

ddη[1]

At the second order, we find a source term, which is quadratic in the first order perturbation. We can thus solve it recursively.

ddη[2]

At the third order, the terms become already more involved - but the scheme continues.

ddη[3]