Linear perturbation of the metric tensor

Preliminaries

Load tensor package

<<xAct`xPert`

Nicer printing

$PrePrint=ScreenDollarIndices;

$CovDFormat="Prefix";

Object definitions

Spacetime manifold

The spacetime manifold M, on which tensors will be defined. Some Greek letters are defined as tangent space indices.

DefManifold[M,4,{α,β,γ,μ,ν,ρ,σ,τ,κ,ξ,ζ}]

Metric

The metric g of signature (-,+,+,+). The Levi-Civita derivative of a tensor (Subscript[A, μ]) will be written as (Subscript[▽, μ])(Subscript[A, ν]) in prefix notation or (Subscript[A, ν;μ]) in postfix notation.

DefMetric[{3,1,0},Met[-μ,-ν],CD,{";","▽"},PrintAs->"g"]

Perturbations of the metric are written as δg.

DefMetricPerturbation[Met,δMet,ϵ,PrintAs->"δg"]

Minkowski metric

We also define the Minkowski metric as a flat metric:

DefMetric[{3,1,0},Mink[-μ,-ν],PD,{",","∂"},FlatMetric->True,PrintAs->"η"]

Taylor series expansion

Definition

Before studying perturbations of the metric tensor and other tensor derived from the metric, it is helpful to briefly recall the Taylor expansion of a function f around some value x:

Series[f[x+δx],{δx,0,3}]

In the following, we will consider only the series up to the first term, which is linear in the perturbation δx of the argument:

Series[f[x+δx],{δx,0,1}]

This is the coefficient of this term

SeriesCoefficient[f[x+δx],{δx,0,1}]

Product rule

Since the linear perturbation is given by the derivative, the product rule holds:

SeriesCoefficient[f[x+δx]g[x+δx],{δx,0,1}]

Inverse rule

Similarly to the product rule, we have the rule

SeriesCoefficient[1/f[x+δx],{δx,0,1}]

Notational conventions

Perturbation of the metric tensor

The metric is expanded in a formal Taylor series expansion, where the n’th perturbation order carries a factor ((ϵ^n)/(n!)) and is written as (Subscript[δg, μν]^n). Here we will be interested only in the linear perturbations.

Perturbed[Met[-μ,-ν],3]

This gives us a particular perturbation order.

Perturbation[Met[-μ,-ν],2]

Perturbation of other tensors

For other tensors, the n’th order perturbation is written as (△^n)[X]:

Perturbation[RicciCD[-μ,-ν],2]

The formal series expansion has the same form:

Perturbed[RicciCD[-μ,-ν],3]

Perturbations

Inverse metric

We start by calculating the perturbation △[({{g, ({{μ, ν}, { ,  }})}})] of inverse ({{g, ({{μ, ν}, { ,  }})}}) of the metric tensor. This can be obtained from two steps. First, note the relation between the metric and its inverse, whose contraction yields a Kronecker symbol:

Inactive[Met[μ,ρ]]Inactive[Met[-ρ,-ν]]
Activate[%]

Second, since the Kronecker symbol does not depend on the metric, its perturbation vanishes:

Perturbation[delta[-μ,ν]]

We can use this to calculate the perturbation of the inverse metric. Here we use the product rule:

Perturbation[Inactive[Met[μ,ρ]]Inactive[Met[-ρ,-σ]]]
Activate[%]
Expand[Met[ν,σ]%]
Solve[%==0,Perturbation[Met[μ,ν]]][[1]]

We can also do so explicitly using the Taylor expansion in the perturbation parameter:

Perturbed[Met[μ,ρ],1]Perturbed[Met[-ρ,-σ],1]
SeriesCoefficient[%,{ϵ,0,1}]
Expand[Met[ν,σ]%]
Solve[%==0,Perturbation[Met[μ,ν]]][[1]]

In other words, the perturbation of the inverse metric is given by taking the negative of the perturbation of the metric, and then raising its indices. This confirms our result:

Perturbation[Met[μ,ν]]
ExpandPerturbation[%]
SeparateMetric[][%]

Christoffel symbols

We then come to the perturbation of the Christoffel symbols. Their definition is well-known:

ChristoffelToGradMetric[ChristoffelCD[μ,-ρ,-ν]]

Since we have already calculated the perturbation of the inverse metric, we can use this formula. The perturbation of the derivative of the metric is just the derivative of the perturbation (partial derivative and perturbing commute):

Inactive[Perturbation[PD[-ρ][Met[-μ,-ν]]]]
Activate[%]

We then use this rule to calculate the perturbation of the Christoffel symbols. It is helpful to realize that the partial derivatives which appear can be rewritten in terms of covariant derivatives, so that in the end all Christoffel symbols cancel:

ChristoffelToGradMetric[ChristoffelCD[μ,-ρ,-ν]];
Perturbation[%];
ExpandPerturbation[%]
ChangeCovD[%,PD,CD];
Expand[%];
ContractMetric[%]
ToCanonical[%];
Simplify[%]
SeparateMetric[][%]

Hence, the perturbation of the Christoffel symbols is given as the covariant derivative of the metric perturbation. This shows us an important property which we will use later: the perturbation of the Christoffel symbols is a tensor. Again we check our result:

Perturbation[ChristoffelCD[μ,-ρ,-ν]]
ExpandPerturbation[%];
SeparateMetric[][%]

Riemann curvature tensor

Next we expand the Riemann curvature tensor. It is defined as follows - note the order of the indices, which is reversed, compared to the most common convention:

RiemannCD[-σ,-ρ,-ν,μ]
ChangeCurvature[%]

We can use this formula to calculate its perturbation. Now we use our previously gained knowledge that the perturbation of the Christoffel symbol is a tensor. We can thus combine partial derivatives and Christoffel symbols to covariant derivatives to get the desired result:

RiemannCD[-σ,-ρ,-ν,μ];
ChangeCurvature[%];
Perturbation[%]
ChangeCovD[%,PD,CD];
ToCanonical[%]
ExpandPerturbation[%];
ToCanonical[%];
Simplify[%]

We see that the perturbation is given by the second covariant derivative of the metric tensor. This confirms our result:

Perturbation[RiemannCD[-σ,-ρ,-ν,μ]]
ExpandPerturbation[%];
Expand[%];
ToCanonical[%];
Simplify[%]

Ricci tensor

We continue with the Ricci tensor, which is obtained by contraction of two indices of the curvature tensor:

Inactive[RiemannCD[-μ,-ρ,-ν,ρ]]
Activate[%]

Contracting two indices on the perturbation of the curvature tensor therefore gives us the desired result:

Perturbation[RiemannCD[-μ,-ρ,-ν,σ]]
ExpandPerturbation[%];
Expand[%];
ToCanonical[%];
Simplify[%]
delta[-σ,ρ]%
Expand[%];
ToCanonical[%];
Simplify[%]

Here two identical terms cancel. This confirms our result:

Perturbation[RicciCD[-μ,-ν]]
ExpandPerturbation[%];
Expand[%];
ToCanonical[%];
Simplify[%]

Ricci scalar

The Ricci scalar is obtained by contracting the Ricci tensor with the metric:

RicciCD[-μ,-ν]Met[μ,ν]

Again we can make use of our previous knowledge and the product rule:

Perturbation[Inactive[RicciCD[-μ,-ν]]Inactive[Met[μ,ν]]];
Activate[%]
ExpandPerturbation[%];
Expand[%];
ToCanonical[%];
Simplify[%]

This can also be obtained directly:

Perturbation[RicciScalarCD[]]
ExpandPerturbation[%];
Expand[%];
ContractMetric[%];
ToCanonical[%];
Simplify[%]

Einstein tensor

Finally, we calculate the perturbation of the Einstein tensor. Its definition is well-known, and so we obtains its perturbation:

EinsteinToRicci[EinsteinCD[-μ,-ν]]
Perturbation[%]
ExpandPerturbation[%];
Expand[%];
ContractMetric[%];
ToCanonical[%];
Simplify[%]

We see that it is significantly more complicated than the perturbation of the Ricci tensor; hence, whenever we consider the perturbation of the vacuum Einstein equations, it is much simpler to consider their trace-reversed form (Subscript[R, μν])=0 instead of (Subscript[G, μν])=0. We finally check:

Perturbation[EinsteinCD[-μ,-ν]]
ExpandPerturbation[%];
Expand[%];
ContractMetric[%];
ToCanonical[%];
Simplify[%]

Perturbations around the Minkowski metric

Collecting perturbations

Recall from the previous section the objects we studied and their perturbations:

tens={Met[-μ,-ν],Met[μ,ν],ChristoffelCD[μ,-ρ,-ν],RiemannCD[-σ,-ρ,-ν,μ],RicciCD[-μ,-ν],RicciScalarCD[],EinsteinCD[-μ,-ν]}
Perturbation/@%;
ExpandPerturbation/@%;
Expand/@%;
ToCanonical/@%;
pert=Simplify/@%;

Setting background to Minkowski

In the following, we will set the metric to the Minkowski metric, and likewise for the inverse:

gtoη=Join[MakeRule[{Met[-μ,-ν],Mink[-μ,-ν]},MetricOn->None,ContractMetrics->False],MakeRule[{Met[μ,ν],InvMink[μ,ν]},MetricOn->None,ContractMetrics->False]]

To translate the perturbations from a general background to a Minkowski background, we perform the following steps:

Bring all indices to their natural position, insert metrics or inverse metrics as needed.

Change all curvature terms to derivatives and products of Christoffel symbols.

Change all covariant derivatives to partial derivatives and Christoffel symbols.

Change all Christoffel symbols to derivatives of the metric.

Replace the metric and its inverse by the Minkowski metric.

pert;
SeparateMetric[]/@%;
ChangeCurvature/@%;
ChangeCovD[#,CD,PD]&/@%;
ChristoffelToGradMetric/@%;
%//.gtoη;
Expand/@%;
ContractMetric/@%;
ToCanonical[#,UseMetricOnVBundle->None]&/@%;
flat=Simplify/@%;

Comparison of results

The following table compares the perturbations around a general background and around the Minkowski metric:

Grid[Prepend[ScreenDollarIndices[Transpose[{tens,pert,flat}]],{"Object","General background metric","Minkowski background"}],Frame->All]