Higher order perturbation of the metric tensor

Preliminaries

Load tensor package

<<xAct`xPert`

Nicer printing

$PrePrint=ScreenDollarIndices;

$CovDFormat="Prefix";

Object definitions

Spacetime manifold

The spacetime manifold M, on which tensors will be defined. Some Greek letters are defined as tangent space indices.

DefManifold[M,4,{α,β,γ,μ,ν,ρ,σ,τ,κ,ξ,ζ}]

Metric

The metric g of signature (-,+,+,+). The Levi-Civita derivative of a tensor (Subscript[A, μ]) will be written as (Subscript[▽, μ])(Subscript[A, ν]) in prefix notation or (Subscript[A, ν;μ]) in postfix notation.

DefMetric[{3,1,0},Met[-μ,-ν],CD,{";","▽"},PrintAs->"g"]

Perturbations of the metric are written as δg.

DefMetricPerturbation[Met,δMet,ϵ,PrintAs->"δg"]

Taylor series expansion

Definition

Before studying perturbations of the metric tensor and other tensor derived from the metric, it is helpful to briefly recall the Taylor expansion of a function f around some value x:

Series[f[x+δx],{δx,0,3}]

Product rule

Since the linear perturbation is given by the derivative, the product rule holds:

Series[f[x+δx]g[x+δx],{δx,0,3}]

Inverse rule

Similarly to the product rule, we have the rule

Series[1/f[x+δx],{δx,0,3}]

Notational conventions

Perturbation of the metric tensor

The metric is expanded in a formal Taylor series expansion, where the n’th perturbation order carries a factor ((ϵ^n)/(n!)) and is written as (Subscript[δg, μν]^n).

Perturbed[Met[-μ,-ν],3]

This gives us a particular perturbation order.

Perturbation[Met[-μ,-ν],2]

We can also obtain it as a series expansion coefficient, given by the derivative.

D[Perturbed[Met[-μ,-ν],3],{ϵ,2}]/.ϵ->0

Perturbation of other tensors

For other tensors, the n’th order perturbation is written as (△^n)[X]:

Perturbation[RicciCD[-μ,-ν],2]

The formal series expansion has the same form:

Perturbed[RicciCD[-μ,-ν],3]

Perturbation of the inverse metric

Relation with the Kronecker symbol

We start by calculating the perturbation △[({{g, ({{μ, ν}, { ,  }})}})] of inverse ({{g, ({{μ, ν}, { ,  }})}}) of the metric tensor. This can be obtained from two steps. First, note the relation between the metric and its inverse, whose contraction yields a Kronecker symbol:

Inactive[Met[μ,ρ]]Inactive[Met[-ρ,-ν]]
Activate[%]

Second, since the Kronecker symbol does not depend on the metric, its perturbation at any positive order vanishes, which we see from the absence of any terms depending on ϵ:

Perturbed[delta[-μ,ν],4]

First order

We can use this to calculate the perturbation of the inverse metric. Here we use the product rule, starting with the first order, to obtain a rule one can use later:

Perturbation[Inactive[Met[μ,ρ]]Inactive[Met[-ρ,-σ]],1];
Activate[%]
Expand[Met[ν,σ]%]
Solve[%==0,Perturbation[Met[μ,ν]]][[1]]
δimet1=MakeRule[Evaluate[List@@(%[[1]])]];

This perturbation can also easily be obtained from the built-in rules, and we see that the result is the same.

Perturbation[Met[μ,ν],1]
ExpandPerturbation[%]
SeparateMetric[][%]

Second order

With the same line of argument, we can derive the second perturbation order. Here we need the result from the first step.

Perturbation[Inactive[Met[μ,ρ]]Inactive[Met[-ρ,-σ]],2];
Activate[%]
%/.δimet1
SeparateMetric[][%];
Expand[Met[ν,σ]%];
ToCanonical[%]
Solve[%==0,Perturbation[Met[μ,ν],2]][[1]]
δimet2=MakeRule[Evaluate[List@@(%[[1]])]];

Again we verify our result.

Perturbation[Met[μ,ν],2]
ExpandPerturbation[%]
SeparateMetric[][%]

General formula for higher orders

Now we aim for a general formula for arbitrary high perturbation orders. We know that the perturbation of the Kronecker symbol vanishes at all orders, and so the following terms vanish by definition.

Table[Perturbation[Inactive[Met[μ,ρ]]Inactive[Met[-ρ,-σ]],k],{k,4}];
Activate[%];
Expand[Met[ν,σ]%];
TableForm[%]

We can obtain this expansion using the Taylor expansion in the perturbation parameter:

Table[D[Perturbed[Met[μ,ρ],k]Perturbed[Met[-ρ,-σ],k],{ϵ,k}]/.ϵ->0,{k,4}];
Expand[Met[ν,σ]%];
TableForm[%]

This can now be written explicitly as a sum over products of perturbations.

Table[Sum[Binomial[k,j]Perturbation[Met[μ,ρ],k-j]Perturbation[Met[-ρ,-σ],j],{j,0,k}],{k,4}];
Expand[Met[ν,σ]%];
TableForm[%]

Note that the first element in this sum is exactly the perturbation we try to solve for. Hence, we can write the orders as follows.

Table[Perturbation[Met[μ,ν],k]->-Expand[Met[ν,σ]Sum[Binomial[k,j]Perturbation[Met[μ,ρ],k-j]Perturbation[Met[-ρ,-σ],j],{j,k}]],{k,4}];
δimet1to4=Flatten[MakeRule[Evaluate[List@@#]]&/@%];
TableForm[%%]

To arrive at the final result, we still need to replace the lower orders which appear on the right hand side of these rules, by recursively applying the lower order rules. Here we contract the metrics, to obtain a more compact result.

Table[Perturbation[Met[μ,ν],k],{k,4}];
%//.δimet1to4;
Expand[%];
ContractMetric/@%;
ToCanonical/@%;
ScreenDollarIndices/@%;
TableForm[%]

This knowledge allows us to define a general formula for arbitrary perturbation order.

δimet[0]:={}

δimet[k_Integer/;k>0]:=Module[{j,μ,ν,ρ,σ,ru},ru=δimet[k-1];Join[ru,MakeRule[Evaluate[{Perturbation[Met[μ,ν],k],-Expand[Met[ν,σ]Sum[Binomial[k,j]Perturbation[Met[μ,ρ],k-j]Perturbation[Met[-ρ,-σ],j],{j,k}]]/.ru}]]]]

This is what we obtain from the function just defined.

Table[Perturbation[Met[μ,ν],k]/.δimet[k],{k,4}];
Expand[%];
ContractMetric/@%;
ToCanonical/@%;
ScreenDollarIndices/@%;
TableForm[%]

We check this result.

Table[Perturbation[Met[μ,ν],k],{k,4}];
ExpandPerturbation/@%;
Expand[%];
ContractMetric/@%;
ToCanonical/@%;
ScreenDollarIndices/@%;
TableForm[%]

Perturbation of the Christoffel symbols

General procedure

To calculate the perturbation of the Christoffel symbols, we first expand them into derivatives of the metric, before we apply the perturbation.

ChristoffelCD[μ,-ρ,-ν]
ChristoffelToGradMetric[%]

First order

We have previously derived that the first order perturbation of the Christoffel symbols is a tensor field, which can be obtained from the covariant derivatives of the metric perturbation.

Perturbation[ChristoffelCD[μ,-ρ,-ν],1]
ExpandPerturbation[%];
SeparateMetric[][%]

Second order

We can use the same strategy to calculate the second order perturbation. First, we expand the Christoffel symbols into metric derivatives, and then perform the perturbative expansion.

ChristoffelCD[μ,-ρ,-ν]
ChristoffelToGradMetric[%]
Perturbation[%,2];
ExpandPerturbation[%]
ChangeCovD[%,PD,CD];
Expand[%];
ContractMetric[%];
ToCanonical[%];
Simplify[%]
SeparateMetric[][%]

Hence, also the second order perturbation of the Christoffel symbols is given as the covariant derivative of the metric perturbation, and thus also a tensor. Again we check our result:

Perturbation[ChristoffelCD[μ,-ρ,-ν],2]
ExpandPerturbation[%];
SeparateMetric[][%]

Higher orders

We finally remark that also higher order perturbations are tensor fields, which are constructed by the same principle. Here we just show a few examples. A general formula can be derived in the same way as for the inverse metric.

Perturbation[ChristoffelCD[μ,-ρ,-ν],3]
ExpandPerturbation[%];
Expand[%];
ToCanonical[%];
Simplify[%]

Perturbation[ChristoffelCD[μ,-ρ,-ν],4]
ExpandPerturbation[%];
Expand[%];
ToCanonical[%];
Simplify[%]

Perturbation of the Riemann curvature tensor

General procedure

Next we expand the Riemann curvature tensor. Here we aim to express it only through the perturbation of the Christoffel symbols, but not break it further down to the metric, which would be lengthy. We thus make use of its definition.

RiemannCD[-σ,-ρ,-ν,μ]
ChangeCurvature[%]

First order

We can use this formula to calculate its perturbation. Now we use our previously gained knowledge that the perturbation of the Christoffel symbol is a tensor. We can thus combine partial derivatives and Christoffel symbols to covariant derivatives to get the desired result:

RiemannCD[-σ,-ρ,-ν,μ];
ChangeCurvature[%];
Perturbation[%,1]
ChangeCovD[%,PD,CD];
ToCanonical[%]

Second order

We continue with the second order. We see that we obtain the same structure. We find a covariant derivative of the perturbation of the Christoffel symbols, and products of lower order perturbations from the quadratic terms.

RiemannCD[-σ,-ρ,-ν,μ];
ChangeCurvature[%];
Perturbation[%,2];
ChangeCovD[%,PD,CD];
ToCanonical[%,UseMetricOnVBundle->None]

Higher orders

To study higher orders, it is instructive to first expand a few terms using the method above and look at their structure.

Table[Perturbation[ChangeCurvature[RiemannCD[-σ,-ρ,-ν,μ]],k],{k,4}];
ChangeCovD[#,PD,CD]&/@%;
ToCanonical[#,UseMetricOnVBundle->None]&/@%;
ScreenDollarIndices/@%;
TableForm[%]

Now it is indeed not difficult to guess a general formula.

Table[CD[-ρ][Perturbation[ChristoffelCD[μ,-σ,-ν],k]]-CD[-σ][Perturbation[ChristoffelCD[μ,-ρ,-ν],k]]+Sum[Binomial[k,j](Perturbation[ChristoffelCD[μ,-ρ,-α],j]Perturbation[ChristoffelCD[α,-σ,-ν],k-j]-Perturbation[ChristoffelCD[μ,-σ,-α],j]Perturbation[ChristoffelCD[α,-ρ,-ν],k-j]),{j,k-1}],{k,4}];
ToCanonical[#,UseMetricOnVBundle->None]&/@%;
ScreenDollarIndices/@%;
TableForm[%]