Newman-Penrose basis and gravitational waves

Preliminaries

Load tensor packages

<<xAct`xPert`

<<xAct`xCoba`

Nicer printing

$PrePrint=ScreenDollarIndices;

$CovDFormat="Prefix";

$CVVerbose=False;

$CIndexForm=True;

Make rules from equations

mkrg[eq_Equal]:=MakeRule[Evaluate[List@@eq],MetricOn->All,ContractMetrics->True]

mkr0[eq_Equal]:=MakeRule[Evaluate[List@@eq],MetricOn->None,ContractMetrics->False]

Object definitions

Spacetime manifold

The spacetime manifold M, on which tensors will be defined. Some Greek letters are defined as tangent space indices.

DefManifold[M,4,{α,β,γ,μ,ν,ρ,σ,τ,ψ,κ,ζ}]

Coordinates

In the following, we will use a coordinate chart (t, x, y, z).

DefTensor[tt[],{M},PrintAs->"t"]

DefTensor[xx[],{M},PrintAs->"x"]

DefTensor[yy[],{M},PrintAs->"y"]

DefTensor[zz[],{M},PrintAs->"z"]

DefChart[coord,M,{0,1,2,3},{tt[],xx[],yy[],zz[]},ChartColor->Blue]

Newman-Penrose basis

The most important step is the introduction of a new, complex, double-null basis, known as the Newman-Penrose basis. This is not a coordinate basis.

DefBasis[newpen,TangentM,{0,1,2,3},BasisChange->CTensor[{{1,0,0,1},{1,0,0,-1}/2,{0,1,I,0}/Sqrt[2],{0,1,-I,0}/Sqrt[2]},{-newpen,coord}],BasisColor->Red]

newpen/:CIndexForm[0,newpen]:="l";

newpen/:CIndexForm[1,newpen]:="n";

newpen/:CIndexForm[2,newpen]:="m";

newpen/:CIndexForm[3,newpen]:="(OverBar[m])";

Metric

The metric g of signature (-,+,+,+). The Levi-Civita derivative of a tensor (Subscript[A, μ]) will be written as (Subscript[▽, μ])(Subscript[A, ν]) in prefix notation or (Subscript[A, ν;μ]) in postfix notation.

DefMetric[{3,1,0},Met[-μ,-ν],CD,{";","▽"},PrintAs->"g"]

DefMetricPerturbation[Met,δMet,ϵ,PrintAs->"h"]

Wave covector

In the following we will study a plane wave, whose propagation is governed by a constant wave covector and frequency.

DefTensor[wav[-μ],{M},PrintAs->"k"]

DefConstantSymbol[freq,PrintAs->"ω"]

Lorentz transformation

We further study Lorentz transformations, which leave the wave covector invariant.

DefTensor[lor[μ,-ν],{M},PrintAs->"Λ"]

DefConstantSymbol[ar,PrintAs->"ℛα"]

DefConstantSymbol[ai,PrintAs->"ℐα"]

DefConstantSymbol[phi,PrintAs->"ϕ"]

Newman-Penrose quantities

The following quantities serve as the relevant components of the curvature tensor in the Newman-Penrose basis.

DefTensor[psi2[],{M},PrintAs->"(Subscript[Ψ, 2])"]

DefTensor[psi3[],{M},PrintAs->"(Subscript[Ψ, 3])"]

DefTensor[psi3b[],{M},PrintAs->"(Subscript[(OverBar[Ψ]), 3])"]

DefTensor[psi4[],{M},PrintAs->"(Subscript[Ψ, 4])"]

DefTensor[psi4b[],{M},PrintAs->"(Subscript[(OverBar[Ψ]), 4])"]

DefTensor[phi22[],{M},PrintAs->"(Subscript[Φ, 22])"]

Scalar field

Finally, we also define a scalar field, so that we can study gravitational waves in scalar-tensor gravity.

DefTensor[scal[],{M},PrintAs->"ψ"]

Component values

Basis transformation

Let us first have a look at the vectors which span the Newman-Penrose basis.  Here are the components of the vectors l, n, m (OverBar[m]), expressed in the coordinate basis.

BasisValues[-newpen,coord]

ToValues[ComponentArray[Basis[{-μ,-newpen},{ν,coord}]]]

Background metric

This is the Minkowski background metric in its familiar form in the coordinate basis.

AllComponentValues[Met[{-μ,-coord},{-ν,-coord}],DiagonalMatrix[{-1,1,1,1}]];

ToValues[ComponentArray[Met[{-μ,-coord},{-ν,-coord}]]]//MatrixForm

Metric in Newman-Penrose basis

We now transform the metric into the Newman-Penrose basis. Note that the diagonal elements vanish, showing that the basis is composed of null vectors.

ChangeComponents[Met[{-μ,-newpen},{-ν,-newpen}],Met[{-μ,-coord},{-ν,-coord}]];

ToValues[ToValues[ComponentArray[Met[{-μ,-newpen},{-ν,-newpen}]]]];
AllComponentValues[Met[{-μ,-newpen},{-ν,-newpen}],%];

ToValues[ComponentArray[Met[{-μ,-newpen},{-ν,-newpen}]]]//MatrixForm

Dependent tensors

Additionally, we compute tensors derived from the metric, such as the Riemann tensor and inverse metric.

MetricCompute[Met,coord,All]

ChangeComponents[Met[{μ,newpen},{ν,newpen}],Met[{μ,coord},{ν,coord}]];

ToValues[ToValues[ComponentArray[Met[{μ,newpen},{ν,newpen}]]]];
AllComponentValues[Met[{μ,newpen},{ν,newpen}],%];

Wave covector

Next, we write the wave covector in coordinates, and transform it into the Newman-Penrose basis.

AllComponentValues[wav[{-μ,-coord}],{1,0,0,-1}freq]

ChangeComponents[wav[{-μ,-newpen}],wav[{-μ,-coord}]];

ToValues[ToValues[ComponentArray[wav[{-μ,-newpen}]]]];
AllComponentValues[wav[{-μ,-newpen}],%]

ChangeComponents[wav[{μ,coord}],wav[{-μ,-coord}]];

ToValues[ToValues[ComponentArray[wav[{μ,coord}]]]];
AllComponentValues[wav[{μ,coord}],%]

ChangeComponents[wav[{μ,newpen}],wav[{-μ,-coord}]];

ToValues[ToValues[ComponentArray[wav[{μ,newpen}]]]];
AllComponentValues[wav[{μ,newpen}],%]

Plane wave

Finally, for the plane wave we will have the property that its derivative is proportional to the wave covector.

{CD[-ρ][δMet[LI[1],-μ,-ν]]==wav[-ρ]δMet[LI[1],-μ,-ν]I,CD[-ρ][scal[]]==wav[-ρ]scal[]I,CD[-ρ][wav[-μ]]==0}
plawa=Flatten[mkrg/@%];

Perturbative expansion and Newman-Penrose variables

Riemann tensor

Let us now calculate the Riemann tensor for a linear perturbation around the Minkowki metric, which is given by a plane wave. Here we also use the fact that the Riemann tensor of the background vanishes to simplify the calculation.

RiemannCD[-σ,-ρ,-ν,-μ]
Perturbation[%];
ExpandPerturbation[%];
%/.RiemannCD->Zero;
%//.plawa;
ContractMetric[%];
ToCanonical[%]
ToBasis[newpen][%];
ComponentArray[%];
ToCanonical[%];
ToValues[%];
AllComponentValues[RiemannCD[-{σ,newpen},-{ρ,newpen},-{ν,newpen},-{μ,newpen}],%];
%[[2]]

Newman-Penrose quantities

We then introduce the definition of the Newman-Penrose quantities. Note the appearance of a factor -(ω^2), indicating a second order derivative of the metric components.

{psi2[]==-RiemannCD[{0,-newpen},{1,-newpen},{0,-newpen},{1,-newpen}]/6,psi3[]==-RiemannCD[{3,-newpen},{1,-newpen},{0,-newpen},{1,-newpen}]/2,psi3b[]==-RiemannCD[{2,-newpen},{1,-newpen},{0,-newpen},{1,-newpen}]/2,psi4[]==-RiemannCD[{3,-newpen},{1,-newpen},{3,-newpen},{1,-newpen}],psi4b[]==-RiemannCD[{2,-newpen},{1,-newpen},{2,-newpen},{1,-newpen}],phi22[]==-RiemannCD[{3,-newpen},{1,-newpen},{2,-newpen},{1,-newpen}]}
npndefeq=ToValues[%]

These are the potentials and the relevant components of the metric perturbation in the Newman-Penrose basis:

nppot=npndefeq[[All,1]]

metpot=Select[Flatten[ComponentArray[δMet[LI[1],-{μ,newpen},-{ν,newpen}]]],Not[FreeQ[npndefeq,#]]&]

For convenience, we introduce some rules to convert between Newman-Penrose variables and metric components.

nptomet=Solve[npndefeq,nppot][[1]]

mettonp=Solve[npndefeq,metpot][[1]]

Lorentz transformation

Ansatz for Lorentz transformation

Let us make the following ansatz for a Lorentz transformation:

AllComponentValues[lor[{μ,newpen},-{ν,newpen}],Transpose[{{1,0,0,0},{ar^2+ai^2,1,Exp[I phi](ar-I ai),Exp[-I phi](ar+I ai)},{ar+I ai,0,Exp[I phi],0},{ar-I ai,0,0,Exp[-I phi]}}]]

Check Lorentz transformations

Check that the ansatz preserves the metric:

Met[-ρ,-σ]lor[ρ,-μ]lor[σ,-ν]-Met[-μ,-ν]
ToBasis[newpen][%];
TraceBasisDummy[%];
ComponentArray[%];
ToCanonical[%];
ToValues[%];
Simplify[%]

Check that the ansatz preserves the wave covector:

wav[-ν]lor[ν,-μ]-wav[-μ]
ToBasis[newpen][%];
TraceBasisDummy[%];
ComponentArray[%];
ToCanonical[%];
ToValues[%];
Simplify[%]

Lorentz transformation of Newman-Penrose quantities

Now we can transform the metric using the Lorentz transformation defined above.

δMet[LI[1],-ρ,-σ]lor[ρ,-μ]lor[σ,-ν]
ToBasis[newpen][%];
TraceBasisDummy[%];
ComponentArray[%];
ToCanonical[%];
ToValues[%];
tramet=Simplify[%];

This is the transformation of the relevant metric components.

TableForm[metru=MapThread[Rule,{metpot,Extract[tramet,Join@@(Position[ComponentArray[δMet[LI[1],-{μ,newpen},-{ν,newpen}]],#]&/@metpot)]},1]]

We can express the rules above also in terms of the Newman-Penrose variables.

TableForm[npru=MapThread[Rule,{nppot,Simplify[nppot/.nptomet/.metru/.mettonp]},1]]

The transformation is governed by the following matrix.

MatrixForm[Transpose[FullSimplify[Coefficient[npru[[All,2]],#]&/@nppot]]]

E(2) class of gravity theories

General relativity

Let us now find the E(2) class of general relativity. We use the fact that we can write the vacuum field equations as (Subscript[R, μν])=0:

RicciCD[-μ,-ν]
Perturbation[%];
ExpandPerturbation[%];
%/.RicciCD->Zero;
%//.plawa;
SeparateMetric[][%];
ToCanonical[%]
ToBasis[newpen][%];
TraceBasisDummy[%];
ComponentArray[%];
ToCanonical[%];
ric=ToValues[%]

Demanding that the above vanishes, we obtain the following conditions on the Newman-Penrose variables:

Reduce[#==0&/@Flatten[ric/.mettonp],nppot]

We see that only the two tensor modes are allowed, while all other modes must vanish. The E(2) class is therefore (Subscript[N, 2]).

Scalar-tensor gravity

We then calculate the E(2) class for scalar-tensor gravity. Let us first check that a plane wave satisfies the scalar field equation (∇^μ)(Subscript[∇, μ])ψ=0.

CD[μ][CD[-μ][scal[]]]
%//.plawa;
ToBasis[newpen][%];
TraceBasisDummy[%];
ToValues[%]

We continue with the metric field equation  (Subscript[R, μν])=(Subscript[∇, μ])(Subscript[∇, ν])ψ. We can use the fact that we already calculated the Ricci tensor.

CD[-μ][CD[-ν][scal[]]]
%//.plawa;
ToBasis[newpen][%];
TraceBasisDummy[%];
ComponentArray[%];
ToCanonical[%];
scaleq=ToValues[%]-ric

These are the conditions on the Newman-Penrose variables.

Reduce[#==0&/@Flatten[scaleq/.mettonp],nppot]

We see that now the breathing mode (Subscript[Φ, 22]) comes with the amplitude of the scalar wave, which may be non-vanishing. The E(2) class is therefore (Subscript[N, 3]).